;
; Reconstruction by John D. Baker, 31 Oct 2026
;
	title	'Floppy-disk boot sector for Davidge DSB 4000'
	page	82
;
$*macro
;
false	equ	0
true	equ	not false
;
jdbfix	equ	false	;true if BIOS fixes enabled
;
test	equ	true	;true to replicate "msize" image,
			;false to generate relocatable image

	maclib	z80
	maclib	flopdef
;
;More/better FD179X command/control/status definitions
;not found in FLOPDEF.LIB -- JDB 6 May 2025
;with thanks to Martin F. Eberhard

;WD1793 commands

RSTRCM  equ     00000000b       ;(I) restore
SEEKCM  equ     00010000b       ;(I) seek
STEPCM  equ     00100000b       ;(I) step
STPICM  equ     01000000b       ;(I) step-in
STPOCM  equ     01100000b       ;(I) step-out
RSECCM  equ     10000000b       ;(II) read sector
WSECCM  equ     10100000b       ;(II) write sector
RADRCM  equ     11000000b       ;(III) read address
RTRKCM  equ     11100000b       ;(III) read track
WTRKCM  equ     11110000b       ;(III) write track
FINTCM  equ     11010000b       ;(IV) force interrupt

;WD1793 command options (1st letter matches WD1793 data sheet)

RS03MS  equ     00000000b       ;(I) 3 mS step rate
RS06MS  equ     00000001b       ;(I) 6 mS step rate
RS10MS  equ     00000010b       ;(I) 10 mS step rate
RS15MS  equ     00000011b       ;(I) 15 mS step rate
VERTRK  equ     00000100b       ;(I) verify on destination track
HDLOAD  equ     00001000b       ;(I) head load
UPDTTR  equ     00010000b       ;(I) update track reg
F1SCMP  equ     00000010b       ;(II)enable side compare
F2SCS1  equ     00001000b       ;(II)side compare, side 1
MULTCM  equ     00010000b       ;(II) read/write multiple
ED15MS  equ     00000100b       ;(II & III) settling delay

;WD1793 status (DSTAT) after a command

SBUSY   equ     00000001b       ;(All) busy
SCRCERR equ     00001000b       ;(All) CRC error
SWRPROT equ     01000000b       ;(All) write protect
SNOTRDY equ     10000000b       ;(All) drive not ready
SINDEX  equ     00000010b       ;(I) index
STRACK0 equ     00000100b       ;(I) track 0
SSEEKER equ     00010000b       ;(I) seek error
SHEADLD equ     00100000b       ;(I) head loaded
SDATRQ  equ     00000010b       ;(II & III) data request
SLOSTD  equ     00000100b       ;(II & III) lost data error
SRNFER  equ     00010000b       ;(II & III) record not found
SRCTYF  equ     00100000b       ;(II & III) record type fault
SWFALT  equ     00100000b       ;(II & III) Write fault

;
;Composite commands used by this program
;
rstnvsl	equ	RSTRCM+RS15MS	;restore, no vfy, slowest step rate
sinvslw	equ	stepi+RS15MS	;step in, w/hdld, updtrk, no vfy,
				;slowest step rate
;
;Composite status bits used by this program
;
t1err	equ	SNOTRDY+DSTRNF+SCRCERR	;not rdy, sekerr, CRC err
rdscerr	equ	t1err+SLOSTD	;not rdy, rnf, CRC err, lost data
;
msize	equ	64		;cp/m version memory size in kilobytes
xtrkb	equ	3		;less this many extra KB for BIOS
xtrpg	equ	2		;plus this many extra pages for BIOS
;
;	"bias" is address offset from 3400h for memory systems larger
;	than 16k (referred to as "b" throughout the text)
;
	if	test
bias	equ	((msize-xtrkb)-20)*1024+xtrpg*256
	else
bias	equ	0		;generate relocatable image
	endif
ccp	equ	3400h+bias	;base of CCP
bdos	equ	ccp+800h	;base of BDOS
bdose	equ	bdos+6		;entry point of BDOS
bios	equ	ccp+1600h	;base of BIOS
;
	if	jdbfix
biosz	equ	94dh		;Davidge FBIOS size
	else
biosz	equ	95bh		;Davidge FBIOS size
	endif
;
syssiz	equ	bios+biosz-ccp
;
;
;Boot ROM sets up Z80 I register, interrupt vectors and default ISR
;for FDC. This program uses Z80 DMAC w/interrupts, so it uses the
;following address for the DMAC interrupt vector.
;
ctc0vec	equ	0058h	;boot ROM sets up vectors here
dmacvec	equ	ctc0vec	;CTC0 never interrupts, so use for DMAC

	org	0080h

cold:	lxi	h,dmacisr
	shld	dmacvec	;set up dmac isr
	mov	e,a	;ROM passes selbits in A, save in E
	res	6,a	;force single density
	out	dctrl1	;select disk
	lxi	h,dmastg  ;hl->dmac init string
	lxi	b,dmastln*256+dmacmd  ;b=len c=DMAC port
	outir		;init, start DMAC
	lxi	b,25*256+1  ;assume 8-in, 25 secs @sec1(+1)
	bit	4,a	;mini disk?
	jrz	load0	;jrif not mini
	mvi	b,17	;else 17 secs
load0:	call	rdtrk
load1:	mov	c,d	;ROM: D=scsz(0-3), in C (B=0), (ofs to SPT)
	mvi	l,spt8	;assume 8-in, HL->spt array
	bit	4,a	;mini disk?
	jrz	load1a	;jrif not mini
	mvi	l,spt5	;else mini, HL->spt array
load1a:	bit	6,a	;trk01+ density?
	jrnz	load1b	;jrif double-density
	inx	h	;else bump to single-density
load1b:	dad	b	;add offset to sector size (0-3)
	mov	b,m	;trk01+ sec/trk in B
	mvi	l,load1	;(H=0)
	push	h	;set up return address
	out	dctrl1	;select disk
	mvi	a,sinvslw  ;A=step-in cmd, no vfy, slowest step rate
	out	dcmmd	;to fdc cmd reg
	hlt		;halt (FDC/CTC3 int wakes us up, A=DSTAT)
	ani	t1err	;check errors
	jrnz	erreot	;jrif any error
	mov	c,a	;A=0, in C for first sector of trk01+
rdtrk:	inr	c	;next sector
	mov	a,c	;in A
	out	dsctr	;to FDC sector reg
	mvi	a,rdsec	;read sector command
	out	dcmmd	;to FDC cmd reg
	ei		;enable ints
	hlt		;halt (FDC/CTC3 int wakes us up, A=DSTAT)
	ani	rdscerr	;test error bits
	jrnz	erreot	;jrif any error
	djnz	rdtrk	;decrement sector count, jrif not 0
erreot:	mov	a,e	;error or end of track, re-get selbits
	rz		;return if no error
	mvi	a,rstnvsl  ;error, restore, novfy, slowest step rate
	out	dcmmd	;to FDC cmd reg
	hlt		;halt, (FDC/CTC3 int wakes us up, A=DSTAT)
	pop	h	;discard return address
	jr	cold	;and start over
dmacisr:
	mvi	a,wdfi	;a=fdc force int cmd
	out	dcmmd	;stop fdc
	mvi	a,0a3h	;DMAC reset+disable interrupts cmd
	out	dmacmd	;reset DMAC, disable DMAC interrupts
	mov	a,e	;selbits back in A
	jmp	bios	;cold boot.
;
;DMAC init string
;
dmastg:	db	0c3h	;wr6: DMAC reset cmd
	db	79h	;wr0: xfr b->a, adr A, len nxt
	dw	ccp	;port A adr, start at CP/M base (CCP)
	dw	22ffh	;xfr len - 1
	db	14h	;wr1: prt A: mem, inc
	db	28h	;wr2: prt B: I/O, fxd
	db	95h	;wr4: byte mode, prt B adr, int ctl nxt
	db	ddata	;FDC data port
	db	12h	;int @ EoBlk, IVL nxt
	db	dmacvec	mod 256  ;DMAC IVL byte (overlays CTC0)
	db	82h	;wr5: stop@end, CE* only, RDY* act low
	db	0cfh	;wr6: ld src (B) adr, clr byt cntr
	db	0abh	;wr6: enable DMAC ints
	db	87h	;wr6: start dmac
dmastln	equ	$-dmastg
;
;	dd128, sd128/dd256, sd256/dd512, sd512/dd1k, sd1k
;sec/trk array for 8-inch disks
spt8:	db	48, 26, 15, 8, 4
;
;sec/trk array for mini disks
spt5:	db	29, 18, 10, 5, 2
;
;pad to 128 bytes
	ds	80h - $ and 7fh
	end

